ZSH CUSTOM FUNCTIONS

PRIMARY CATEGORY → ZSH

In this Setup environment, all the following Shell Functions are declared in the custom.zsh script

Then, the custom.zsh script is sourced from the .zshrc file as follows →

# ~/.zshrc - Custom Functions
if [[ -f /home/al3xbb/.config/zsh/src/custom.zsh ]] ; then
    source /home/al3xbb/.config/zsh/src/custom.zsh
fi

IMPORTANT

In the above code, an absolute path is used instead of the Tilde Expansion ~

This is because the Root’s .zshrc file is a symbolic link to the non-privilege user’s .zshrc

Note that the .config/zsh directory only exists in /home/al3xbb but not in /root

Reference

Custom.zsh Source File → See here

Terminal/Screen

Shell Functions related to the Terminal and Screen actions →

clearScreenAndScrollback

Reference

It clears the Screen Content and Scrollback Buffer through the C-l keybind

Function

clearScreenAndScrollback ()
{
    clear && printf '\e[3J'
    zle && zle .reset-prompt && zle -R
}

zle -N clearScreenAndScrollback
bindkey '^L' clearScreenAndScrollback

More info here

Pentesting

Shell Functions related to the Pentesting Process →

Most of the functions are Non-POSIX-Compliant as ZSH is the Targeted Shell

mkt

It creates a Pentesting Folder Structure to store all documentation related to the target 🎯

Function

mkt()
{
        local -- _dir=
        local -a -- _dirs=(
                evidence
                logs
                scans
                scope
                tools
        )
 
        for _dir in "${_dirs[@]}"
        do
                mkdir -p -- "$_dir"
 
                [[ $_dir == "evidence" ]] &&
 
                        mkdir -p -- "$_dir"/{creds,data,screenshots}
        done
}

IMPORTANT

Note that the above function is Non-POSIX Compliant due to Bash Specific Functionalities such as local, [[ ]] shell keyword, Brace Expansion { } or indexed arrays

Therefore, It is not destined to POSIX Compliant shells like sh or dash

If POSIX Compliant is needed →

mkt()
{
        _dir= _dirs="evidence logs scans scope tools"
 
        for _dir in $_dirs
        do
                mkdir -p -- "$_dir"
 
                [ "$_dir" = "evidence" ] &&
 
                        mkdir -p -- "$_dir"/creds \
                                    "$_dir"/data \
                                    "$_dir"/screenshot
        done
 
}

validateIP

This function simply checks if the IP Address entered as an argument is valid

It is used by the setTarget function

Function

validateIP ()
{
    local _IP=$1 _octet=
 
    [[ $_IP =~ ^[0-9]+(\.[0-9]+){3}$ ]] || return 1
 
    while read -rd '.' _octet
    do
        (( _octet > 255 )) && return 1
 
    done <<< "$_IP".
 
    return 0
}

setTarget

It sets the Target’s IP Address and Hostname as one of the Polybar Bar’s Modules

This function prints the above data into the /home/al3xbb/.config/bin/target file

Then the Polybar Module carries out an action based on that File’s Content as follows →

• If Empty → “No target” as Polybar’s Bar Content
• If not Empty → File’s Content as the Polybar’s Bar Content, i.e. the IP Address and Hostame

Function

setTarget ()
{
    local -- _IP=$1 _machineName=$2 \
             _targetFile=/home/al3xbb/.config/bin/target
 
    (( $# != 2 )) && {
 
        /bin/cat <<HELP 1>&2
 
  [!] This function requires two arguments: IP Addresss and Machine Name
 
    Syntax: setTarget XXX.XXX.XXX.XXX "Machine Name"
HELP
        return 1
    }
 
    validateIP "$_IP" || {
        printf "\n%s\n" '[!] First arg must be a valid IP Address' 1>&2
        return 1
    }
 
    [[ -n $_IP && -n $_machineName ]] || {
 
        printf "\n%s\n" '[!] Args cannot be an empty string' 1>&2
        return 1
    }
 
    printf "%s:%s\n" "$_IP" "$_machineName" > "$_targetFile"
}

clearTarget

This functions empties the /home/al3xbb/.config/bin/target file

Therefore, as mentioned in the setTarget function, the Polybar Module sets “No Target” as Polybar Bar’s Content

Function

clearTarget ()
{
    local -- _targetFile=/home/al3xbb/.config/bin/target
 
    [[ -s $_targetFile ]] && : '' > "$_targetFile" || return 1
}